Baoding-FenShuaJiang
/
Green_GoodERP18_FSJ_Standard
Beobachten 1
Favorisieren 0
Wiki 捐赠
gooderp18绿色标准版
Du kannst nicht mehr als 25 Themen auswählen Themen müssen entweder mit einem Buchstaben oder einer Ziffer beginnen. Sie können Bindestriche („-“) enthalten und bis zu 35 Zeichen lang sein.
Struktur: 0f75e31513
Branches Tags
${ item.name }
Erstelle Branch ${ searchTerm }
von „0f75e31513“
${ noResults }
Green_GoodERP18_FSJ_Standard/gooderp18/server/setup/win32/setup.nsi

599 Zeilen
22KB
Originalformat Blame Verlauf 

  1. # Part of Odoo. See LICENSE file for full copyright and licensing details.

  2. 

  3. # TODO: Avoid to uninstall the database

  4. # TODO: We can update the server or the clients without to uninstall the all-in-one

  5. # TODO: Add startmenu handling (link to localhost + uninstall)

  6. 

  7. Unicode True

  8. 

  9. !include 'MUI2.nsh'

  10. !include 'FileFunc.nsh'

  11. !include 'LogicLib.nsh'

  12. !include 'Sections.nsh'

  13. !include 'x64.nsh'

  14. 

  15. !macro IfKeyExists ROOT MAIN_KEY KEY

  16.     # This macro comes from http://nsis.sourceforge.net/Check_for_a_Registry_Key

  17.     Push $R0

  18.     Push $R1

  19.     Push $R2

  20. 

  21.     # XXX bug if ${ROOT}, ${MAIN_KEY} or ${KEY} use $R0 or $R1

  22. 

  23.     StrCpy $R1 "0" # loop index

  24.     StrCpy $R2 "0" # not found

  25. 

  26.     ${Do}

  27.         EnumRegKey $R0 ${ROOT} "${MAIN_KEY}" "$R1"

  28.         ${If} $R0 == "${KEY}"

  29.             StrCpy $R2 "1" # found

  30.             ${Break}

  31.         ${EndIf}

  32.         IntOp $R1 $R1 + 1

  33.     ${LoopWhile} $R0 != ""

  34. 

  35.     ClearErrors

  36. 

  37.     Exch 2

  38.     Pop $R0

  39.     Pop $R1

  40.     Exch $R2

  41. !macroend

  42. 

  43. !define PUBLISHER 'Odoo S.A.'

  44. 

  45. !ifndef MAJOR_VERSION

  46.     !define MAJOR_VERSION '15'

  47. !endif

  48. 

  49. !ifndef MINOR_VERSION

  50.     !define MINOR_VERSION '0'

  51. !endif

  52. 

  53. !ifndef REVISION_VERSION

  54.     !define REVISION_VERSION 'alpha1'

  55. !endif

  56. 

  57. !ifndef VERSION

  58.     !define VERSION "${MAJOR_VERSION}.${MINOR_VERSION}"

  59. !endif

  60. 

  61. !ifndef PYTHONVERSION

  62. 	!define PYTHONVERSION '3.10.11'

  63. !endif

  64. 

  65. !ifndef SERVICENAME

  66. 	!define SERVICENAME 'odoo-server-${VERSION}'

  67. !endif

  68. 

  69. !ifndef TOOLSDIR

  70. 	!define TOOLSDIR 'c:\odoobuild'

  71. !endif

  72. 

  73. !define PRODUCT_NAME "Odoo"

  74. !define DISPLAY_NAME "${PRODUCT_NAME} ${MAJOR_VERSION}.${MINOR_VERSION}"

  75. 

  76. !define UNINSTALL_BASE_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall"

  77. !define UNINSTALL_REGISTRY_KEY "${UNINSTALL_BASE_REGISTRY_KEY}\${DISPLAY_NAME}"

  78. 

  79. !define UNINSTALL_REGISTRY_KEY_SERVER "${UNINSTALL_BASE_REGISTRY_KEY}\Odoo Server ${VERSION}"

  80. 

  81. !define REGISTRY_KEY "SOFTWARE\${DISPLAY_NAME}"

  82. 

  83. !define DEFAULT_POSTGRESQL_HOSTNAME 'localhost'

  84. !define DEFAULT_POSTGRESQL_PORT 5432

  85. !define DEFAULT_POSTGRESQL_USERNAME 'openpg'

  86. !define DEFAULT_POSTGRESQL_PASSWORD 'openpgpwd'

  87. 

  88. Name '${DISPLAY_NAME}'

  89. Caption "${PRODUCT_NAME} ${VERSION} Setup"

  90. OutFile "${TOOLSDIR}\server\odoo_setup_${VERSION}.exe"

  91. SetCompressor /SOLID /FINAL lzma

  92. ShowInstDetails hide

  93. 

  94. BrandingText '${PRODUCT_NAME} ${VERSION}'

  95. 

  96. RequestExecutionLevel admin

  97. 

  98. !insertmacro GetParameters

  99. !insertmacro GetOptions

  100. 

  101. Var Option_AllInOne

  102. Var HasPostgreSQL

  103. Var cmdLineParams

  104. 

  105. Var TextPostgreSQLHostname

  106. Var TextPostgreSQLPort

  107. Var TextPostgreSQLUsername

  108. Var TextPostgreSQLPassword

  109. 

  110. Var HWNDPostgreSQLHostname

  111. Var HWNDPostgreSQLPort

  112. Var HWNDPostgreSQLUsername

  113. Var HWNDPostgreSQLPassword

  114. 

  115. Var ProxyTokenDialog

  116. Var ProxyTokenLabel

  117. Var ProxyTokenText

  118. Var ProxyTokenPwd

  119. 

  120. !define STATIC_PATH "static"

  121. !define PIXMAPS_PATH "${STATIC_PATH}\pixmaps"

  122. 

  123. !define MUI_ABORTWARNING

  124. !define MUI_ICON "${PIXMAPS_PATH}\odoo-icon.ico"

  125. 

  126. !define MUI_WELCOMEFINISHPAGE_BITMAP "${PIXMAPS_PATH}\odoo-intro.bmp"

  127. !define MUI_UNWELCOMEFINISHPAGE_BITMAP "${PIXMAPS_PATH}\odoo-intro.bmp"

  128. !define MUI_HEADERIMAGE

  129. !define MUI_HEADERIMAGE_BITMAP "${PIXMAPS_PATH}\odoo-slogan.bmp"

  130. !define MUI_HEADERIMAGE_BITMAP_NOSTRETCH

  131. !define MUI_HEADER_TRANSPARENT_TEXT ""

  132. 

  133. !insertmacro MUI_PAGE_WELCOME

  134. !insertmacro MUI_PAGE_LICENSE "${STATIC_PATH}\doc\LICENSE"

  135. !define MUI_COMPONENTSPAGE_SMALLDESC

  136. !define MUI_PAGE_CUSTOMFUNCTION_LEAVE ComponentLeave

  137. !insertmacro MUI_PAGE_COMPONENTS

  138. Page Custom ShowPostgreSQL LeavePostgreSQL

  139. !define MUI_PAGE_CUSTOMFUNCTION_LEAVE dir_leave

  140. !insertmacro MUI_PAGE_DIRECTORY

  141. !insertmacro MUI_PAGE_INSTFILES

  142. Page Custom ShowProxyTokenDialogPage

  143. !define MUI_FINISHPAGE_NOAUTOCLOSE

  144. !define MUI_FINISHPAGE_RUN

  145. !define MUI_FINISHPAGE_RUN_CHECKED

  146. !define MUI_FINISHPAGE_RUN_TEXT "$(DESC_FinishPageText)"

  147. !define MUI_FINISHPAGE_RUN_FUNCTION "LaunchLink"

  148. !define MUI_FINISHPAGE_LINK $(DESC_FinishPage_Link)

  149. !define MUI_FINISHPAGE_LINK_LOCATION "https://www.odoo.com/page/contactus"

  150. !insertmacro MUI_PAGE_FINISH

  151. 

  152. !insertmacro MUI_UNPAGE_WELCOME

  153. !insertmacro MUI_UNPAGE_CONFIRM

  154. !insertmacro MUI_UNPAGE_INSTFILES

  155. !insertmacro MUI_UNPAGE_FINISH

  156. 

  157. !insertmacro MUI_LANGUAGE "English"

  158. !insertmacro MUI_LANGUAGE "French"

  159. !insertmacro MUI_RESERVEFILE_LANGDLL

  160. 

  161. ; English

  162. LangString DESC_Odoo_Server ${LANG_ENGLISH} "Install the Odoo Server with all the Odoo standard modules."

  163. LangString DESC_PostgreSQL ${LANG_ENGLISH} "Install the PostgreSQL RDBMS used by Odoo."

  164. LangString DESC_FinishPage_Link ${LANG_ENGLISH} "Contact Odoo for Partnership and/or Support"

  165. LangString DESC_AtLeastOneComponent ${LANG_ENGLISH} "You have to choose at least one component"

  166. LangString DESC_CanNotInstallPostgreSQL ${LANG_ENGLISH} "You can not install the PostgreSQL database without the Odoo Server"

  167. LangString WARNING_HostNameIsEmpty ${LANG_ENGLISH} "The hostname for the connection to the PostgreSQL Server is empty"

  168. LangString WARNING_UserNameIsEmpty ${LANG_ENGLISH} "The username for the connection to the PostgreSQL Server is empty"

  169. LangString WARNING_PasswordIsEmpty ${LANG_ENGLISH} "The password for the connection to the PostgreSQL Server is empty"

  170. LangString WARNING_PortIsWrong ${LANG_ENGLISH} "The port for the connexion to the PostgreSQL Server is wrong (default: 5432)"

  171. LangString DESC_PostgreSQLPage ${LANG_ENGLISH} "Configure the information for the PostgreSQL connection"

  172. LangString DESC_PostgreSQL_Hostname ${LANG_ENGLISH} "Hostname"

  173. LangString DESC_PostgreSQL_Port ${LANG_ENGLISH} "Port"

  174. LangString DESC_PostgreSQL_Username ${LANG_ENGLISH} "Username"

  175. LangString DESC_PostgreSQL_Password ${LANG_ENGLISH} "Password"

  176. LangString Profile_AllInOne ${LANG_ENGLISH} "Odoo Server And PostgreSQL Server"

  177. LangString Profile_Server ${LANG_ENGLISH} "Odoo Server Only"

  178. LangString Profile_IOT ${LANG_ENGLISH} "Odoo IoT"

  179. LangString TITLE_Odoo_Server ${LANG_ENGLISH} "Odoo Server"

  180. LangString TITLE_PostgreSQL ${LANG_ENGLISH} "PostgreSQL Database"

  181. LangString TITLE_IOT ${LANG_ENGLISH} "Odoo IoT"

  182. LangString TITLE_Nginx ${LANG_ENGLISH} "Nginx WebServer"

  183. LangString TITLE_Ghostscript ${LANG_ENGLISH} "Ghostscript interpreter"

  184. LangString DESC_FinishPageText ${LANG_ENGLISH} "Start Odoo"

  185. LangString UnsafeDirText ${LANG_ENGLISH} "Installing outside of $PROGRAMFILES64 is not recommended.$\nDo you want to continue ?"

  186. 

  187. ; French

  188. LangString DESC_Odoo_Server ${LANG_FRENCH} "Installation du Serveur Odoo avec tous les modules Odoo standards."

  189. LangString DESC_PostgreSQL ${LANG_FRENCH} "Installation de la base de données PostgreSQL utilisée par Odoo."

  190. LangString DESC_FinishPage_Link ${LANG_FRENCH} "Contactez Odoo pour un Partenariat et/ou du Support"

  191. LangString DESC_AtLeastOneComponent ${LANG_FRENCH} "Vous devez choisir au moins un composant"

  192. LangString DESC_CanNotInstallPostgreSQL ${LANG_FRENCH} "Vous ne pouvez pas installer la base de données PostgreSQL sans le serveur Odoo"

  193. LangString WARNING_HostNameIsEmpty ${LANG_FRENCH} "L'adresse pour la connection au serveur PostgreSQL est vide"

  194. LangString WARNING_UserNameIsEmpty ${LANG_FRENCH} "Le nom d'utilisateur pour la connection au serveur PostgreSQL est vide"

  195. LangString WARNING_PasswordIsEmpty ${LANG_FRENCH} "Le mot de passe pour la connection au serveur PostgreSQL est vide"

  196. LangString WARNING_PortIsWrong ${LANG_FRENCH} "Le port pour la connection au serveur PostgreSQL est erroné (défaut: 5432)"

  197. LangString DESC_PostgreSQLPage ${LANG_FRENCH} "Configurez les informations de connection pour le serveur PostgreSQL"

  198. LangString DESC_PostgreSQL_Hostname ${LANG_FRENCH} "Hôte"

  199. LangString DESC_PostgreSQL_Port ${LANG_FRENCH} "Port"

  200. LangString DESC_PostgreSQL_Username ${LANG_FRENCH} "Utilisateur"

  201. LangString DESC_PostgreSQL_Password ${LANG_FRENCH} "Mot de passe"

  202. LangString Profile_AllInOne ${LANG_FRENCH} "Serveur Odoo Et Serveur PostgreSQL"

  203. LangString Profile_Server ${LANG_FRENCH} "Seulement Le Serveur Odoo"

  204. LangString Profile_IOT ${LANG_FRENCH} "Odoo IoT"

  205. LangString TITLE_Odoo_Server ${LANG_FRENCH} "Serveur Odoo"

  206. LangString TITLE_PostgreSQL ${LANG_FRENCH} "Installation du serveur de base de données PostgreSQL"

  207. LangString TITLE_IOT ${LANG_FRENCH} "Odoo IoT"

  208. LangString TITLE_Nginx ${LANG_FRENCH} "Installation du serveur web Nginx"

  209. LangString TITLE_Ghostscript ${LANG_FRENCH} "Installation de l'interpréteur Ghostscript"

  210. LangString DESC_FinishPageText ${LANG_FRENCH} "Démarrer Odoo"

  211. LangString UnsafeDirText ${LANG_FRENCH} "Installer en dehors de $PROGRAMFILES64 n'est pas recommandé.$\nVoulez-vous continuer ?"

  212. 

  213. InstType /NOCUSTOM

  214. InstType $(Profile_AllInOne)

  215. InstType $(Profile_Server)

  216. InstType $(Profile_IOT)

  217. 

  218. Section $(TITLE_Odoo_Server) SectionOdoo_Server

  219.     SectionIn 1 2 3

  220. 

  221.     # Installing winpython

  222.     SetOutPath "$INSTDIR\python"

  223.     File /r /x "__pycache__" "${TOOLSDIR}\WinPy64\python-${PYTHONVERSION}.amd64\*"

  224. 

  225.     SetOutPath "$INSTDIR\nssm"

  226.     File /r /x "src" "${TOOLSDIR}\nssm-2.24\*"

  227. 

  228.     SetOutPath "$INSTDIR\server"

  229.     File /r /x "wkhtmltopdf" /x "enterprise" "${TOOLSDIR}\server\*"

  230. 

  231.     SetOutPath "$INSTDIR\vcredist"

  232.     File /r "${TOOLSDIR}\vcredist\*.exe"

  233. 

  234.     # Install Visual C redistribuable files

  235.     DetailPrint "Installing Visual C++ redistributable files"

  236.     nsExec::Exec '"$INSTDIR\vcredist\vc_redist.x64.exe" /q'

  237. 

  238.     SetOutPath "$INSTDIR\thirdparty"

  239.     File /r "${TOOLSDIR}\wkhtmltopdf\*"

  240. 

  241.     # If there is a previous install of the Odoo Server, keep the login/password from the config file

  242.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "db_host" $TextPostgreSQLHostname

  243.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "db_user" $TextPostgreSQLUsername

  244.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "db_password" $TextPostgreSQLPassword

  245.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "db_port" $TextPostgreSQLPort

  246.     # Fix the addons path

  247.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "addons_path" "$INSTDIR\server\odoo\addons"

  248.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "bin_path" "$INSTDIR\thirdparty"

  249.     # Set data_dir

  250.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "data_dir" "$INSTDIR\sessions"

  251. 

  252.     # if we're going to install postgresql force it's path,

  253.     # otherwise we consider it's always done and/or correctly tune by users

  254.     ${If} $HasPostgreSQL == 0

  255.         WriteIniStr "$INSTDIR\server\odoo.conf" "options" "pg_path" "$INSTDIR\PostgreSQL\bin"

  256.     ${EndIf}

  257. 

  258.     # Productivity Apps

  259.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "default_productivity_apps" "True"

  260.     DetailPrint "Installing Windows service"

  261.     nsExec::ExecTOLog '"$INSTDIR\python\python.exe" "$INSTDIR\server\odoo-bin" --stop-after-init -c "$INSTDIR\server\odoo.conf" --logfile "$INSTDIR\server\odoo.log" -s'

  262.     nsExec::ExecToLog '"$INSTDIR\nssm\win64\nssm.exe" install ${SERVICENAME} "$INSTDIR\python\python.exe"'

  263.     nsExec::ExecToLog '"$INSTDIR\nssm\win64\nssm.exe" set ${SERVICENAME} AppDirectory "$\"$INSTDIR\python$\""'

  264.     nsExec::ExecToLog '"$INSTDIR\nssm\win64\nssm.exe" set ${SERVICENAME} AppParameters "\"$INSTDIR\server\odoo-bin\" -c "\"$INSTDIR\server\odoo.conf\"'

  265.     nsExec::ExecToLog '"$INSTDIR\nssm\win64\nssm.exe" set ${SERVICENAME} ObjectName "LOCALSERVICE"'

  266.     AccessControl::GrantOnFile  "$INSTDIR" "LOCALSERVICE" "FullAccess"

  267. 

  268.     Call RestartOdooService

  269. SectionEnd

  270. 

  271. Section $(TITLE_PostgreSQL) SectionPostgreSQL

  272.     SectionIn 1

  273.     SetOutPath '$TEMP'

  274.     VAR /GLOBAL postgresql_exe_filename

  275.     VAR /GLOBAL postgresql_url

  276. 

  277.     StrCpy $postgresql_exe_filename "postgresql-12.4-1-windows-x64.exe"

  278. 

  279.     StrCpy $postgresql_url "https://get.enterprisedb.com/postgresql/$postgresql_exe_filename"

  280.     nsExec::Exec 'net user openpgsvc /delete'

  281. 

  282.     DetailPrint "Downloading PostgreSQl"

  283.     NScurl::http get "$postgresql_url" "$TEMP/$postgresql_exe_filename" /PAGE /END

  284.     pop $0

  285. 

  286.     ReadRegStr $0 HKLM "System\CurrentControlSet\Control\ComputerName\ActiveComputerName" "ComputerName"

  287.     StrCmp $0 "" win9x

  288.     Goto done

  289.     win9x:

  290.         ReadRegStr $0 HKLM "System\CurrentControlSet\Control\ComputerName\ComputerName" "ComputerName"

  291.     done:

  292.     Rmdir /r "$INSTDIR\PostgreSQL"

  293.     DetailPrint "Installing PostgreSQL"

  294.     ExecWait '"$TEMP\$postgresql_exe_filename" \

  295.         --mode unattended \

  296.         --prefix "$INSTDIR\PostgreSQL" \

  297.         --datadir "$INSTDIR\PostgreSQL\data" \

  298.         --servicename "PostgreSQL_For_Odoo" \

  299.         --serviceaccount "openpgsvc" --servicepassword "0p3npgsvcPWD" \

  300.         --superaccount "$TextPostgreSQLUsername" --superpassword "$TextPostgreSQLPassword" \

  301.         --serverport $TextPostgreSQLPort'

  302. SectionEnd

  303. 

  304. Section $(TITLE_IOT) IOT

  305.     SectionIn 3

  306.     DetailPrint "Configuring TITLE_IOT"

  307.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "server_wide_modules" "web,hw_posbox_homepage,hw_drivers"

  308.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "list_db" "False"

  309.     WriteIniStr "$INSTDIR\server\odoo.conf" "options" "max_cron_threads" "0"

  310.     nsExec::ExecToStack '"$INSTDIR\python\python.exe" "$INSTDIR\server\odoo-bin" genproxytoken'

  311.     pop $0

  312.     pop $ProxyTokenPwd

  313. SectionEnd

  314. 

  315. 

  316. Section $(TITLE_Nginx) Nginx

  317.     SectionIn 3

  318.     SetOutPath '$TEMP'

  319.     VAR /GLOBAL nginx_zip_filename

  320.     VAR /GLOBAL nginx_url

  321. 

  322.     # need unzip plugin:

  323.     # https://nsis.sourceforge.io/mediawiki/images/5/5a/NSISunzU.zip

  324.     StrCpy $nginx_zip_filename "nginx-1.22.0.zip"

  325.     StrCpy $nginx_url "https://nginx.org/download/$nginx_zip_filename"

  326. 

  327.     DetailPrint "Downloading Nginx"

  328.     NScurl::http get "$nginx_url" "$TEMP\$nginx_zip_filename" /PAGE /END

  329.     DetailPrint "Temp dir: $TEMP\$nginx_zip_filename"

  330.     DetailPrint "Unzip Nginx"

  331.     nsisunz::UnzipToLog "$TEMP\$nginx_zip_filename" "$INSTDIR"

  332. 

  333.     Pop $0

  334.     StrCmp $0 "success" ok

  335.       DetailPrint "$0" ;print error message to log

  336.     ok:

  337. 

  338.     FindFirst $0 $1 "$INSTDIR\nginx*"

  339.     DetailPrint "Setting up nginx"

  340.     SetOutPath "$INSTDIR\$1\conf"

  341.     CreateDirectory $INSTDIR\$1\temp

  342.     CreateDirectory $INSTDIR\$1\logs

  343.     FindClose $0

  344.     File "conf\nginx\nginx.conf"

  345.     # Temporary certs for the first start

  346.     File "..\..\odoo\addons\point_of_sale\tools\posbox\overwrite_after_init\etc\ssl\certs\nginx-cert.crt"

  347.     File "..\..\odoo\addons\point_of_sale\tools\posbox\overwrite_after_init\etc\ssl\private\nginx-cert.key"

  348. SectionEnd

  349. 

  350. Section $(TITLE_Ghostscript) SectionGhostscript

  351.     SectionIn 3

  352.     SetOutPath '$TEMP'

  353.     VAR /GLOBAL ghostscript_exe_filename

  354.     VAR /GLOBAL ghostscript_url

  355. 

  356.     StrCpy $ghostscript_exe_filename "gs10012w64.exe"

  357.     StrCpy $ghostscript_url "https://github.com/ArtifexSoftware/ghostpdl-downloads/releases/download/gs10012/$ghostscript_exe_filename"

  358. 

  359.     DetailPrint "Downloading Ghostscript"

  360.     NScurl::http get "$ghostscript_url" "$TEMP\$ghostscript_exe_filename" /PAGE /END

  361.     DetailPrint "Temp dir: $TEMP\$ghostscript_exe_filename"

  362. 

  363.     Rmdir /r "INSTDIR\Ghostscript"

  364.     DetailPrint "Installing Ghostscript"

  365.     ExecWait '"$TEMP\$ghostscript_exe_filename" \

  366.         /S \

  367.         /D=$INSTDIR\Ghostscript'

  368.     Call RestartOdooService

  369. SectionEnd

  370. 

  371. Section -Post

  372.     WriteRegExpandStr HKLM "${UNINSTALL_REGISTRY_KEY}" "UninstallString" "$INSTDIR\Uninstall.exe"

  373.     WriteRegExpandStr HKLM "${UNINSTALL_REGISTRY_KEY}" "InstallLocation" "$INSTDIR"

  374.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "DisplayName" "${DISPLAY_NAME}"

  375.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "DisplayVersion" "${MAJOR_VERSION}.${MINOR_VERSION}"

  376.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "Publisher" "${PUBLISHER}"

  377.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "HelpLink" "support@odoo.com"

  378.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "HelpTelephone" "+32.81.81.37.00"

  379.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "URLInfoAbout" "https://www.odoo.com"

  380.     WriteRegStr HKLM       "${UNINSTALL_REGISTRY_KEY}" "Contact" "sales@odoo.com"

  381.     WriteRegDWORD HKLM     "${UNINSTALL_REGISTRY_KEY}" "NoModify" "1"

  382.     WriteRegDWORD HKLM     "${UNINSTALL_REGISTRY_KEY}" "NoRepair" "1"

  383.     WriteUninstaller "$INSTDIR\Uninstall.exe"

  384. SectionEnd

  385. 

  386. !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN

  387.     !insertmacro MUI_DESCRIPTION_TEXT ${SectionOdoo_Server} $(DESC_Odoo_Server)

  388.     !insertmacro MUI_DESCRIPTION_TEXT ${SectionPostgreSQL} $(DESC_PostgreSQL)

  389. !insertmacro MUI_FUNCTION_DESCRIPTION_END

  390. 

  391. Section "Uninstall"

  392.     # Check if the server is installed

  393.     !insertmacro IfKeyExists "HKLM" "${UNINSTALL_REGISTRY_KEY_SERVER}" "UninstallString"

  394.     Pop $R0

  395.     ReadRegStr $0 HKLM "${UNINSTALL_REGISTRY_KEY_SERVER}" "UninstallString"

  396.     ExecWait '"$0" /S'

  397.     ExecWait '"$INSTDIR\Ghostscript\uninstgs.exe" /S'

  398. 

  399.     nsExec::Exec "net stop ${SERVICENAME}"

  400.     nsExec::Exec "sc delete ${SERVICENAME}"

  401.     sleep 2

  402. 

  403.     Rmdir /r "$INSTDIR\server"

  404.     Rmdir /r "$INSTDIR\sessions"

  405.     Rmdir /r "$INSTDIR\thirdparty"

  406.     Rmdir /r "$INSTDIR\python"

  407.     Rmdir /r "$INSTDIR\nssm"

  408.     FindFirst $0 $1 "$INSTDIR\nginx*"

  409.     Rmdir /R "$INSTDIR\$1"

  410.     FindClose $0

  411.     DeleteRegKey HKLM "${UNINSTALL_REGISTRY_KEY}"

  412. SectionEnd

  413. 

  414. Function .onInit

  415.     VAR /GLOBAL previous_install_dir

  416.     SetRegView 64

  417.     ReadRegStr $previous_install_dir HKLM "${REGISTRY_KEY}" "Install_Dir"

  418.     ${If} $previous_install_dir == ""

  419.         StrCpy $INSTDIR "$PROGRAMFILES64\Odoo ${VERSION}"

  420.         WriteRegStr HKLM "${REGISTRY_KEY}" "Install_dir" "$INSTDIR"

  421.     ${Else}

  422.         StrCpy $INSTDIR $previous_install_dir

  423.     ${EndIf}

  424. 

  425.     Push $R0

  426.     ${GetParameters} $cmdLineParams

  427.     ClearErrors

  428.     Pop $R0

  429. 

  430.     StrCpy $Option_AllInOne 0

  431.     StrCpy $HasPostgreSQL 0

  432. 

  433.     StrCpy $TextPostgreSQLHostname ${DEFAULT_POSTGRESQL_HOSTNAME}

  434.     StrCpy $TextPostgreSQLPort ${DEFAULT_POSTGRESQL_PORT}

  435.     StrCpy $TextPostgreSQLUsername ${DEFAULT_POSTGRESQL_USERNAME}

  436.     StrCpy $TextPostgreSQLPassword ${DEFAULT_POSTGRESQL_PASSWORD}

  437. 

  438.     Push $R0

  439.     ${GetOptions} $cmdLineParams '/allinone' $R0

  440.     IfErrors +2 0

  441.     StrCpy $Option_AllInOne 1

  442.     Pop $R0

  443. 

  444.     StrCmp $Option_AllInOne 1 AllInOneMode

  445.     StrCmp $Option_AllInOne 0 NoAllInOneMode

  446. 

  447.     AllInOneMode:

  448.         MessageBox MB_OK|MB_ICONINFORMATION "All In One"

  449. 

  450.     NoAllInOneMode:

  451. 

  452.     !insertmacro MUI_LANGDLL_DISPLAY

  453. 

  454.     ClearErrors

  455.     EnumRegKey $0 HKLM "SOFTWARE\PostgreSQL\Installations" 0

  456.     IfErrors DoInstallPostgreSQL 0

  457.     StrCmp $0 "" DoInstallPostgreSQL

  458.     StrCpy $HasPostgreSQL 1

  459.     !insertmacro UnselectSection ${SectionPostgreSQL}

  460.     SectionSetFlags ${SectionPostgreSQL} ${SF_RO}

  461. 

  462.     DoInstallPostgreSQL:

  463. FunctionEnd

  464. 

  465. Function .onSelChange

  466.     ${If} $HasPostgreSQL == 1

  467.         !insertmacro UnselectSection ${SectionPostgreSQL}

  468.     ${EndIf}

  469. FunctionEnd

  470. 

  471. Function PostgreSQLOnBack

  472. FunctionEnd

  473. 

  474. Function ShowPostgreSQL

  475.     GetCurInstType $R0

  476.     IntCmp $R0 1 bypassPostgresConfig

  477.     Intcmp $R0 2 bypassPostgresConfig

  478. 

  479.     nsDialogs::Create /NOUNLOAD 1018

  480.     Pop $0

  481. 

  482.     ${If} $0 == error

  483.         Abort

  484.     ${EndIf}

  485. 

  486.     GetFunctionAddress $0 PostgreSQLOnBack

  487.     nsDialogs::OnBack $0

  488. 

  489.     ${NSD_CreateLabel} 0 0 100% 10u $(DESC_PostgreSQLPage)

  490.     Pop $0

  491. 

  492.     ${NSD_CreateLabel} 0 45 60u 12u $(DESC_PostgreSQL_Hostname)

  493.     Pop $0

  494.     ${NSD_CreateText} 100 45 150u 12u $TextPostgreSQLHostname

  495.     Pop $HWNDPostgreSQLHostname

  496. 

  497.     ${NSD_CreateLabel} 0 75 60u 12u $(DESC_PostgreSQL_Port)

  498.     Pop $0

  499.     ${NSD_CreateNumber} 100 75 150u 12u $TextPostgreSQLPort

  500.     Pop $HWNDPostgreSQLPort

  501.     ${NSD_CreateLabel} 0 105 60u 12u $(DESC_PostgreSQL_Username)

  502.     Pop $0

  503.     ${NSD_CreateText} 100 105 150u 12u $TextPostgreSQLUsername

  504.     Pop $HWNDPostgreSQLUsername

  505.     ${NSD_CreateLabel} 0 135 60u 12u $(DESC_PostgreSQL_Password)

  506.     Pop $0

  507.     ${NSD_CreateText} 100 135 150u 12u $TextPostgreSQLPassword

  508.     Pop $HWNDPostgreSQLPassword

  509. 

  510.     nsDialogs::Show

  511.     bypassPostgresConfig:

  512. FunctionEnd

  513. 

  514. Function LeavePostgreSQL

  515.     ${NSD_GetText} $HWNDPostgreSQLHostname $TextPostgreSQLHostname

  516.     ${NSD_GetText} $HWNDPostgreSQLPort $TextPostgreSQLPort

  517.     ${NSD_GetText} $HWNDPostgreSQLUsername $TextPostgreSQLUsername

  518.     ${NSD_GetText} $HWNDPostgreSQLPassword $TextPostgreSQLPassword

  519.     StrLen $1 $TextPostgreSQLHostname

  520.     ${If} $1 == 0

  521.         MessageBox MB_ICONEXCLAMATION|MB_OK $(WARNING_HostNameIsEmpty)

  522.         Abort

  523.     ${EndIf}

  524. 

  525.     ${If} $TextPostgreSQLPort <= 0

  526.     ${OrIf} $TextPostgreSQLPort > 65535

  527.         MessageBox MB_ICONEXCLAMATION|MB_OK $(WARNING_PortIsWrong)

  528.         Abort

  529.     ${EndIf}

  530. 

  531.     StrLen $1 $TextPostgreSQLUsername

  532.     ${If} $1 == 0

  533.         MessageBox MB_ICONEXCLAMATION|MB_OK $(WARNING_UserNameIsEmpty)

  534.         Abort

  535.     ${EndIf}

  536. 

  537.     StrLen $1 $TextPostgreSQLPassword

  538.     ${If} $1 == 0

  539.         MessageBox MB_ICONEXCLAMATION|MB_OK $(WARNING_PasswordIsEmpty)

  540.         Abort

  541.     ${EndIf}

  542. FunctionEnd

  543. 

  544. Function ShowProxyTokenDialogPage

  545.     GetCurInstType $R0

  546.     IntCmp $R0 2 doProxyToken bypassProxyToken

  547.     doProxyToken:

  548.         nsDialogs::Create 1018

  549.         Pop $ProxyTokenDialog

  550.         ${IF} $ProxyTokenDialog == !error

  551.             Abort

  552.         ${EndIf}

  553. 

  554.         ${NSD_CreateLabel} 0 0 100% 25% "Here is your access token for the Odoo IOT, please write it down in a safe place, you will need it to configure the IOT"

  555.         Pop $ProxyTokenLabel

  556. 

  557.         ${NSD_CreateText} 0 30% 100% 13u $ProxyTokenPwd

  558.         Pop $ProxyTokenText

  559.         ${NSD_Edit_SetreadOnly} $ProxyTokenText 1

  560.         ${NSD_AddStyle}  $ProxyTokenText ${SS_CENTER}

  561.         nsDialogs::Show

  562.     bypassProxyToken:

  563. FunctionEnd

  564. 

  565. Function ComponentLeave

  566.     SectionGetFlags ${SectionOdoo_Server} $0

  567.     IntOp $0 $0 & ${SF_SELECTED}

  568.     IntCmp $0 ${SF_SELECTED} Done

  569. 

  570.     SectionGetFlags ${SectionPostgreSQL} $0

  571.     IntOp $0 $0 & ${SF_SELECTED}

  572.     IntCmp $0 ${SF_SELECTED} DontInstallPostgreSQL

  573. 

  574.     DontInstallPostgreSQL:

  575.         MessageBox MB_ICONEXCLAMATION|MB_OK $(DESC_CanNotInstallPostgreSQL)

  576.         Abort

  577.     Done:

  578. FunctionEnd

  579. 

  580. Function LaunchLink

  581.     ExecShell "open" "http://localhost:8069/"

  582. FunctionEnd

  583. 

  584. Function RestartOdooService

  585.     DetailPrint "Restarting Odoo Service"

  586.     ExecWait "net stop ${SERVICENAME}"

  587.     ExecWait "net start ${SERVICENAME}"

  588. FunctionEnd

  589. 

  590. Function dir_leave

  591.     StrLen $0 $PROGRAMFILES64

  592.     StrCpy $0 $INSTDIR $0

  593.     StrCmp $0 $PROGRAMFILES64 continue

  594.     MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(UnsafeDirText)" IDYES continue IDNO aborting

  595.     aborting:

  596.         Abort

  597.     continue:

  598. FunctionEnd
上海开阖软件有限公司 沪ICP备12045867号-1